Migrating to KTS build script

Also bumps the versions as
- Kotlin to 1.3.61

Using java-platform plugin for sharing most of the library versions.
Using buildSrc for versions that are used for both classpath and dependency dependencies to keep it minimal because changing the code under buildSrc invalidates the entire gradle cache.

Bug: 148411262
Change-Id: If7235501f87ca8116d9a0a2040ea6feccc481da6

Author: thagikura

.gitignore

@@ -25,7 +25,7 @@ local.properties
 .DS_Store
 
 # IDEA/Android Studio project files, because
-# the project can be imported from settings.gradle
+# the project can be imported from settings.gradle.kts
 *.iml
 .idea/*
 !.idea/copyright

androidTest-shared/build.gradle renamed to androidTest-shared/build.gradle.kts

@@ -1,5 +1,5 @@
 /*
- * Copyright 2018 Google LLC
+ * Copyright 2020 Google LLC
  *
  * Licensed under the Apache License, Version 2.0 (the "License");
  * you may not use this file except in compliance with the License.
@@ -14,31 +14,35 @@
  * limitations under the License.
  */
 
-apply plugin: 'com.android.library'
-apply plugin: 'kotlin-android'
+plugins {
+    id("com.android.library")
+    kotlin("android")
+}
 
 android {
-    compileSdkVersion rootProject.compileSdkVersion
+    compileSdkVersion(Versions.COMPILE_SDK)
     defaultConfig {
-        minSdkVersion rootProject.minSdkVersion
-        targetSdkVersion rootProject.targetSdkVersion
-        versionCode 1
-        versionName "1.0"
+        minSdkVersion(Versions.MIN_SDK)
+        targetSdkVersion(Versions.TARGET_SDK)
+        versionCode = 1
+        versionName = "1.0"
 
-        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
+        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
     }
 
     lintOptions {
         // Version changes are beyond our control, so don't warn. The IDE will still mark these.
-        disable 'GradleDependency'
+        disable("GradleDependency")
     }
 }
 
 dependencies {
-    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$rootProject.kotlinVersion"
+    api(platform(project(":depconstraints")))
+
+    implementation(Libs.KOTLIN_STDLIB)
 
     // Architecture Components
-    implementation "androidx.lifecycle:lifecycle-extensions:$rootProject.lifecycleVersion"
-    implementation "androidx.lifecycle:lifecycle-livedata:$rootProject.lifecycleVersion"
-    implementation "androidx.lifecycle:lifecycle-viewmodel:$rootProject.lifecycleVersion"
+    implementation(Libs.LIFECYCLE_EXTENSIONS)
+    implementation(Libs.LIFECYCLE_LIVE_DATA)
+    implementation(Libs.LIFECYCLE_VIEW_MODEL)
 }

ar/build.gradle

@@ -0,0 +1,67 @@
+/*
+ * Copyright 2020 Google LLC
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     https://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+plugins {
+    id("com.android.library")
+    kotlin("android")
+    kotlin("kapt")
+}
+
+android {
+    compileSdkVersion(Versions.COMPILE_SDK)
+    defaultConfig {
+        minSdkVersion(Versions.MIN_SDK)
+        targetSdkVersion(Versions.TARGET_SDK)
+        versionCode = 1
+        versionName = "1.0"
+        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
+        consumerProguardFiles("consumer-proguard-rules.pro")
+    }
+
+    buildTypes {
+        maybeCreate("staging")
+        getByName("staging") {
+            initWith(getByName("debug"))
+
+            // Specifies a sorted list of fallback build types that the
+            // plugin should try to use when a dependency does not include a
+            // "staging" build type.
+            // Used with :test-shared, which doesn't have a staging variant.
+            matchingFallbacks = listOf("debug")
+        }
+    }
+
+    lintOptions {
+        disable("InvalidPackage")
+        // Version changes are beyond our control, so don't warn. The IDE will still mark these.
+        disable("GradleDependency")
+    }
+
+    // Required by ArWebView
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_1_8
+        targetCompatibility = JavaVersion.VERSION_1_8
+    }
+}
+
+dependencies {
+    api(platform(project(":depconstraints")))
+    implementation(project(":shared"))
+    implementation(Libs.APPCOMPAT)
+    implementation(Libs.ARCORE)
+    implementation(Libs.GOOGLE_PLAY_SERVICES_VISION)
+    implementation(Libs.KOTLIN_STDLIB)
+}